ROLL_OVER与MOUSE_OVER的调度的区别
- 可视组件在鼠标进入该组件时会调度MOUSE_OVER事件,即使是从其子组件移到该组件依然会触发该事件。
- 可视组件在鼠标从不是其子组件的其余组件中进入该组件时会调度ROLL_OVER事件,直观来看,就是鼠标从外部移入该组件才调用。
ROLL_OUT与MOUSE_OUT的调度的区别
- 可视组件在鼠标移出该组件时会调度MOUSE_OUT事件,即使是移到该组件的子组件依然会触发该事件。
- 可视组件在鼠标移到不是其子组件的其余组件中会调度ROLL_OUT事件,直观来看,就是鼠标移到该组件外部才调用。
在含有子组件的可视组件上监听四个事件
- 鼠标由外部进入母组件时能监听到由母组件调度的ROLL_OVER与MOUSE_OVER事件;
-
鼠标由母组件进入子组件时能监听到由子组件调度的MOUSE_OVER事件和母组件调度的MOUSE_OUT事件;
- 此时子组件还调度了ROLL_OVER事件,但是由于ROLL_OVER没有冒泡阶段(详见AS3:事件流机制),因此其母组件不能监听到该事件;
-
鼠标由子组件移到母组件时能监听到由子组件调度的MOUSE_OUT事件和母组件调度的MOUSE_OVER事件;
- 同样的,此时子组件还调度了ROLL_OUT事件,但是母组件同样监听不到;
- 鼠标由母组件移到外部时能监听到由母组件调度的ROLL_OUT与MOUSE_OUT事件;
总结
MOUSE事件与ROLL事件的区别在于如下两点:
- 鼠标在母组件与子组件上移入移出时是否调度的区别。
- MOUSE事件具有冒泡阶段而ROLL事件没有,决定了在子组件调度事件时母组件是否能监听到的区别。
总之,ROLL事件将整个母组件包括其子组件看成一个组件,移入移出整个组件的边界时母组件才调度事件并能监听该事件。
FLASH示例
在母容器设置监听这四个事件,显示内容前一个为调度事件来源,后一个为调度的事件名称。
package
{
import flash.display.MovieClip;
import flash.display.Sprite;
import flash.events.MouseEvent;
public class MouseEvents extends Sprite
{
public function MouseEvents()
{
init();
}
private function init():void
{
var sp:Sprite=new MovieClip();
addChild(sp);
sp.graphics.beginFill(0xff0000);
sp.graphics.drawCircle(0,0,50);
sp.graphics .endFill();
sp.x=stage.stageWidth/2;
sp.y=stage.stageHeight/2;
var sp1:Sprite=new Sprite();
sp.addChild(sp1);
sp1.graphics.beginFill(0xff7700);
sp1.graphics.drawCircle(0,0,25);
sp1.graphics .endFill();
sp.addEventListener(MouseEvent.MOUSE_OVER,onMRO);
sp.addEventListener(MouseEvent.MOUSE_OUT,onMRO);
sp.addEventListener(MouseEvent.ROLL_OVER,onMRO);
sp.addEventListener(MouseEvent.ROLL_OUT,onMRO);
sp.addEventListener(MouseEvent.MOUSE_WHEEL,onMRO);
sp1.addEventListener(MouseEvent.MOUSE_OVER,onMRO);
sp1.addEventListener(MouseEvent.MOUSE_OUT,onMRO);
sp1.addEventListener(MouseEvent.ROLL_OVER,onMRO);
sp1.addEventListener(MouseEvent.ROLL_OUT,onMRO);
sp1.addEventListener(MouseEvent.MOUSE_WHEEL,onMRO);
}
public function onMRO(e:MouseEvent):void
{
trace("目标对象:"+e.target+" 当前对象:"+e.currentTarget+" 事件类型:"+e.type+" 事件阶段:"+e.eventPhase);
}
}
}
鼠标光标移动过程:从舞台空白地方移入sp,再移入sp1,然后再逆向移动。结果如下:
目标对象:[object MovieClip] 当前对象:[object MovieClip] 事件类型:rollOver 事件阶段:2
目标对象:[object MovieClip] 当前对象:[object MovieClip] 事件类型:mouseOver 事件阶段:2
目标对象:[object MovieClip] 当前对象:[object MovieClip] 事件类型:mouseOut 事件阶段:2
目标对象:[object Sprite] 当前对象:[object Sprite] 事件类型:rollOver 事件阶段:2
目标对象:[object Sprite] 当前对象:[object Sprite] 事件类型:mouseOver 事件阶段:2
目标对象:[object Sprite] 当前对象:[object MovieClip] 事件类型:mouseOver 事件阶段:3
目标对象:[object Sprite] 当前对象:[object Sprite] 事件类型:mouseWheel 事件阶段:2
目标对象:[object Sprite] 当前对象:[object MovieClip] 事件类型:mouseWheel 事件阶段:3
目标对象:[object Sprite] 当前对象:[object Sprite] 事件类型:mouseOut 事件阶段:2
目标对象:[object Sprite] 当前对象:[object MovieClip] 事件类型:mouseOut 事件阶段:3
目标对象:[object Sprite] 当前对象:[object Sprite] 事件类型:rollOut 事件阶段:2
目标对象:[object MovieClip] 当前对象:[object MovieClip] 事件类型:mouseOver 事件阶段:2
目标对象:[object MovieClip] 当前对象:[object MovieClip] 事件类型:mouseOut 事件阶段:2
目标对象:[object MovieClip] 当前对象:[object MovieClip] 事件类型:rollOut 事件阶段:2
分享到:
相关推荐
教师资格证考试_教育知识与能力__简答题__辨析题__材料分析
20210129-东兴证券-低温奶行业系列深度(一):辨析行业,找寻未来,低温跑出黄金赛道.pdf
低温奶行业系列深度(一):辨析行业,找寻未来,低温跑出黄金赛道.pdf
辨析used_to_do_be_used_to_doingbe_used_to_do.ppt
2021版高考语文一轮复习第3板块语言文字运用8正确使用词语包括熟语2词语近义辨析__明确“3大设题角度”“6大辨析方法”课件
专题六:辨析并修改病句.pdf
2020云南教师资格考试综合知识与能力:辨析题答题策略.pdf
九年级政治中考专题训练: 辨析题素材全国通用.doc
公务员考试行测:辨析考点和题型让你更专业.pdf
2021年考研《教育学》试题及答案:辨析题.pdf
2020云南教师资格考试综合知识与能力:辨析之派生类属和相关类属.pdf
(二班五组)李怀仁:辨析病句之结构混乱.pptx
201年招标师考试案例分析题知识点总结:辨析题6.pdf
教育领域中的人工智能:概念辨析、应用隐忧与解决途径
低温奶行业系列深度(一):辨析行业,找寻未来,低温跑出黄金赛道
教育领域中的人工智能:概念辨析、应用隐忧与解决途径.pdf
安徽省长丰县实验高级中学2017届高考语文一轮复习教案:辨析并修改病句(含反思).pdf
高三语文上学期(9、10、11)月考试题分类汇编: 辨析并修改病句全国通用 试题.doc
2020届高三语文上学期(9、10、11)月考试题分类汇编: 辨析并修改病句全国通用.doc
低温奶行业系列深度(一):辨析行业,找寻未来,低温跑出黄金赛道(2021)(20页).pdf